unix crypt() fun posted by Alain O'Dea @ Wed, 07 May 2008 02:03:01 -0000

Alain O'Dea — Wed, 07 May 2008 02:03:01 -0000

OTP R12B includes the Crypto Application:
http://www.erlang.org/doc/apps/crypto/index.html

I’m not sure how complete it is. My understanding is that ejabberd includes a more complete OpenSSL implementation which they need for SSL Jabber/XMPP.

Erlang Python Example posted by Alain O'Dea @ Wed, 07 May 2008 02:00:05 -0000

Alain O'Dea — Wed, 07 May 2008 02:00:05 -0000

Very nice Stephan. Thank you for posting that. I was looking for a cleaner way to do communication between Erlang and Python. I could not figure out how to make Python implementation for the ports example.

Until now I have been using TCP/IP line-based communication. I could not figure out how to get the packet size thing to work. If you are interested I have included my old approach below.

TCP line-based integration with Erlang:

-module (echo_server).
-export([start/0]).

start() ->
    {ok, Listen} = gen_tcp:listen(4321, [list, {packet, line},
                                         {reuseaddr, true},
                                         {active, true}]),
    spawn(fun() -> par_connect(Listen) end).

par_connect(Listen) ->
    {ok, Socket} = gen_tcp:accept(Listen),
    spawn(fun() -> par_connect(Listen) end),
    io:format("Client connected~n"),
    echo(Socket). 

echo(Socket) ->
    receive
        {tcp, Socket, Line} ->
            gen_tcp:send(Socket, Line),
            echo(Socket);
        {tcp_closed, Socket} ->
            io:format("Client disconnected~n")
    end.

Telnet can then be used to test the interface: telnet 127.0.0.1 4321. Once you are satisfied it is very easy to build a TCP client in Python. I used this to implement a very basic Erlang code completion server for use with TextMate.

Some question about Chapter.14 (How to execute string) posted by Alain O'Dea @ Wed, 07 May 2008 01:33:05 -0000

Alain O'Dea — Wed, 07 May 2008 01:33:05 -0000

lib_misc:string2value/1 is implemented as follows:

string2value(Str) ->
    {ok, Tokens, _} = erl_scan:string(Str ++ "."),
    {ok, Exprs} = erl_parse:parse_exprs(Tokens),
    Bindings = erl_eval:new_bindings(),
    {value, Value, _} = erl_eval:exprs(Exprs, Bindings),
    Value.

I could not find a direct equivalent to Python’s exec statement in the modules shipped with Erlang OTP R12B.

The entire set of example code for Programming Erlang is available for download here:
http://www.pragprog.com/titles/jaerlang/source_code

unix crypt() fun posted by Marco Romano @ Mon, 28 Apr 2008 13:00:54 -0000

Marco Romano — Mon, 28 Apr 2008 13:00:54 -0000

Hello folks,

do you know if exist an erlang implementation of unix crypt() function ? Thanks.

Erlang Python Example posted by Stephan Nies @ Mon, 28 Apr 2008 12:22:33 -0000

Stephan Nies — Mon, 28 Apr 2008 12:22:33 -0000

Hello,
I am just learning Erlang. But since much of my
codebase is in Python i wanted to interface Erlang and
Python. So i ported the ports example in Chapter 12.1 to Python.

I thought that might be of interest for some other
people using Erlang and Python. So here is the link:

“http://www.physik.uni-dortmund.de/~nies/example1.py”

You can just use it as a replacement for the C-code,
just make sure to rename it to example1, make it executeable
and place it in the same dir as example1.erl

Oh and while searching the net for python <-> erlang examples
I found this neat project using twisted to interface with erlang: https://launchpad.net/twotp

Cheers,
Stephan

Some question about Chapter.14 (How to execute string) posted by Yuichi Ito @ Fri, 25 Apr 2008 07:27:36 -0000

Yuichi Ito — Fri, 25 Apr 2008 07:27:36 -0000

Hello.
I want to execute the code of Chap14 “start_nano_server()”.

But there is no function “lib_misc:string2value(String)”.
So, I checked this book’s index(reference?), and searched in Google.
But couldn’t find both.

this function acts like this
> lib_misc:string2value(“list_to_tuple([2+3*4,10+20])”).
{14,30}

How do I create this function?
Or, is there a function which execute string like Python’s “exec Statement”?

Thsnks
(I’m using Japanese editon, so there may be little difference in English edition)

Erlang control Java? posted by Alain O'Dea @ Wed, 02 Apr 2008 03:15:49 -0000

Alain O'Dea — Wed, 02 Apr 2008 03:15:49 -0000

If you use open_port({spawn, "command"}, [stream]) you will be able to use standard IO streams on the Java side and message send and receive operations on the Erlang side. There is also a line option which might be useful. Just make sure to use a PrintWriter or some other buffered output stream and call flush() from the Java side to send a message.

An Erlang module to dump content into the Mac OS X clipboard using the pbcopy program:

copy(Data) ->
    Clipboard = open_port({spawn, "pbcopy"}, [stream]),
    Clipboard ! {self(), {command, Data}},
    Clipboard ! {self(), close},
    receive
        {Clipboard, closed} -> true
    end.

If you bring up the Erlang docs for open_port on http://www.gotapi.com/ it explains how to communicate with the port.

RSA encryption posted by Alain O'Dea @ Wed, 02 Apr 2008 03:06:30 -0000

Alain O'Dea — Wed, 02 Apr 2008 03:06:30 -0000

Take a look at the ejabberd libraries http://www.ejabberd.im/

The ejabberd guys implemented SSL and a bunch of other very useful libs for Erlang.

CEAN http://cean.process-one.net/packages/ and Jungerl http://jungerl.sourceforge.net/ are decent sources for stuff like this as well. Jungerl is not for the feint of heart, but they have a lot of projects for wrapping the best of breed GNU and BSD libraries.

Chapter 8 Problems posted by Alain O'Dea @ Wed, 02 Apr 2008 02:59:30 -0000

Alain O'Dea — Wed, 02 Apr 2008 02:59:30 -0000

I posted a reply to your blog, but it was dark and appears to have been eaten by a grue :(

Side effect posted by Alain O'Dea @ Wed, 02 Apr 2008 02:57:18 -0000

Alain O'Dea — Wed, 02 Apr 2008 02:57:18 -0000

My understanding (Joe, correct me if I am wrong), is that the term Side effect is used in the book to mean anything that alters state outside of the current function being executed.

All Variables in Erlang are either bound or unbound. Once bound through matching in an expression an Erlang Variable cannot be changed. What appears to be an assignment operator (the ”=” sign) is in actual fact a constraint expression declaring the left and right hand sides of the expression to be equal.

Writing X = 1 followed by X = 2 will fail on X = 2 because X has already been constrained to equal 1 by X = 1. This pattern matching mechanism requires rethinking the design of state and variables in a program. IMHO, the end result is more comprehensible code that is easier to reason about and explain to others.

In Erlang an expression cannot directly modify the state of another function or even other expressions in the same scope. All such modifications are explicitly made through the interpretation of messages or function parameters. By Chapter 3 you have not gotten to see Message Passing or Concurrency. It should hopefully be clearer at that point.

I check this board frequently so please post your questions here. I will do my best to help :)

E is for excellent: Appendix E posted by Alain O'Dea @ Wed, 02 Apr 2008 02:41:37 -0000

Alain O'Dea — Wed, 02 Apr 2008 02:41:37 -0000

Don’t forget to read Appendix E. It explains many of the tools that come with Erlang like Code Coverage, Profiler, and Cross-reference analyzers.

It also gives a quick overview of the Debugger and debugging technique, provides some explanation of the errors the Compiler generates, and explains how to use the Tracing tool.

Seriously, read Appendix E. It takes Erlang programming from a design exercise to a seriously pragmatic and productive endeavor. I went from running mind-experiments of my code to doing unit testing with coverage analysis within an hour of skimming over Appendix E.

These tools are all invoked using Erlang code. This makes automating workflows that use them surprisingly easy and convenient.

A module called project which I created to handle builds and coverage for a game server I am writing:

-module(project).
-author('alain.odea').
-license('http://opensource.org/licenses/afl-3.0.php').
-export([make/0, cover/0]).

each(Fun) ->
    lists:map(Fun, [actor, escrow, game, hex, inner_perimeter, 
                    intersection, outer_perimeter, path, player,
                    server, status, stockpile, test_game]).

make() ->
    each(fun(Mod) -> shell_default:c(Mod, [debug_info]) end).

cover() ->
    cover:start(),
    each(fun cover:compile/1),
    test_game:run(),
    each(fun cover:analyse_to_file/1).

code:get_path / code:add_path posted by Alain O'Dea @ Sat, 22 Mar 2008 22:52:58 -0000

Alain O'Dea — Sat, 22 Mar 2008 22:52:58 -0000

The path list can be modified because it is maintained by a separate process. The state around the receive statement in that process can be changed by recursion.

code:call/1 invokes code_server:call/1 which sends a message to the code server process. Upon receiving a path addition message the code_server process calls the function that receives code_server commands again recursively with a modified version of the list. Single assignment is preserved in this manner.

Chapter 8 Problems posted by Christopher Atkins @ Tue, 11 Mar 2008 01:42:36 -0000

Christopher Atkins — Tue, 11 Mar 2008 01:42:36 -0000

Hi all! Man, I’m loving Erlang. It’s nice to be excited about programming again. Thanks JOE!!

I completed problem 2, and I was hoping someone might give me some pointers.

Side effect posted by Alexey Kuznetsov @ Thu, 06 Mar 2008 22:41:10 -0000

Alexey Kuznetsov — Thu, 06 Mar 2008 22:41:10 -0000

I already finish 3 chapters, but still don’t understand what mean that expression? I know only side effect in C++ or other imperative languages.

RSA encryption posted by richard bucker @ Wed, 05 Mar 2008 22:27:36 -0000

richard bucker — Wed, 05 Mar 2008 22:27:36 -0000

I’d really like to use openssl’s RSA_encryption() or the RSA_mod_exp()... but I’m having a hard time generating the appropriate prime numbers. Seems to me that the openssl integration was only partially completed.

Can anyone make recommendations? What about explaining why the libs are incomplete?

Erlang control Java? posted by Chris Liaw @ Wed, 05 Mar 2008 03:50:43 -0000

Chris Liaw — Wed, 05 Mar 2008 03:50:43 -0000

Hi,

After i read the book of Pragmatic Erlang, i got bought into the Erlang. However, since my previous project is all Java, i do have some Java library which is not available in Erlang such as complete cryptographic library.

I am pretty much wanted to use Erlang distributed, concurrency and fault torelant in my program but i also need the java cryptographic library. Hence i am thinking of creating a java program which is capable to be controlled by Erlang.

I tried the JInterface, it works but i am exploring to use Java port, which is the IO communication of Java program with Erlang node. However, i can not seems to get it working. Is there any specific steps which i need to do to allow Erlang can send and receive messages via open_port() with Java program?

Thanks.

Regards,
Chris

code:get_path / code:add_path posted by Mike Lutz @ Mon, 03 Mar 2008 01:56:54 -0000

Mike Lutz — Mon, 03 Mar 2008 01:56:54 -0000

code:getpath() returns a list of the current directories searched for modules. This list can be modified by code:add_patha() and code:add_pathz() and a bunch of their cousins. This looks like a violation of the one assignment rule – otherwise, how can code:get_path() return different values at different times?

The source code shows add_patha as:

add_patha(Dir) when is_list(Dir) -> call({add_path,first,Dir}).

and I can’t find any documentation on “call”, so my suspicion is that it’s some internal mumbo-jumbo in the interpreter, but I’d love to have this explained. A form of continuation??

MJL

2.6 One time assigments posted by Alain O'Dea @ Wed, 27 Feb 2008 00:56:13 -0000

Alain O'Dea — Wed, 27 Feb 2008 00:56:13 -0000

Iterative or repeating algorithms are fairly easy to port from an imperative language (like Java) to Erlang.

For example, you want to gather some interesting property from a set of items.

In Java you would use a for loop and an accessor method:

void process(List list) {
    List output = new ArrayList();
    for (Item item : list) {
        output.add(item.getInterestingProperty());
    }
    return output;
}

In Erlang you would fold the list and extract the property with pattern matching:

process(List) ->
    lists:foldl(fun process/2, [], List).

process(#item{interestingProperty=InterestingProperty}, Output) ->
    [InterestingProperty|Output].

2.6 One time assigments posted by Joe Armstrong @ Tue, 26 Feb 2008 10:04:34 -0000

Joe Armstrong — Tue, 26 Feb 2008 10:04:34 -0000

Good question !

Erlang has no loops or for/next cycles so the problem does not occur.

Basically you cannot say X = X + 1, you have to invent a new variable X1 and make sure that X1 goes “out of scope”.

So the old code (in an imperative language)

foo(X) {
    X = X + 1,
    Y = bar(X),
    ho(X, Y),
    joe(Y).
}

becomes

foo(X) -> 
    X1 = X + 1,
    Y = bar(X1),
    ho(X1, Y),
    %% At this point X1 is no longer referred to so the space for X1 can  be freed
    joe(Y).

We now call joe(Y) but where does joe(Y) return to? – to the end of foo(X) where it finds a return instruction
ultimately joe(Y) returns to the place that called foo(X) – the point is that Y is never refereed to again
in the body of foo(X) and can be garbage collected.

So we create new variables X1, X2, X3, .... and the space for these can be reclaimed
when the program can no longer access these variables.

To get the effect of a loop we write a tail-recursive recursive function. So to sum the integers from 1 to N
we might write.

sum(N) -> sum(N, 0).

sum(0, Sum) -> Sum;
sum(N, Sum) -> Sum1 = Sum + 1, %% create a new value of Sum N1 = N – 1, %% and a new value of N sum(N1, Sum1). %% call sum (again)

The last line (which calls sum) merely jumps to the start of the sum routine. Although this is a call
the system does not return to site of the call, since this merely returns immediately, instead it returns,
(this is called “last-call” optimization). Having jumped to the start of sum the variables
N1 and Sum1 are out of scope and can never be accessed again, so they get garbaged. The Erlang compiler
recognises things like this and attempts to save space by storing N1 in the register used for N (if this
is possible).

This above code is a loop (after compilation)

BTW We’d really write the second clause of sum as:

sum(N, Sum) -> sum(N-1, Sum+N)

Without the temporary variables. The version I wrote was so you can see what happens to the variables.

Hope that helps!

/Joe

2.6 One time assigments posted by Alexey Kuznetsov @ Tue, 26 Feb 2008 08:14:52 -0000

Alexey Kuznetsov — Tue, 26 Feb 2008 08:14:52 -0000

I agree. And i see that style is a good style. But really i try to imagine situation that can totally brake that logic – loops. If you try use loops in any languages you must reuse loop iterator all time. And that is a question – how to solve that. There Joe explain new style, but don’t explain main differents between languages.

2.6 One time assigments posted by Alain O'Dea @ Tue, 26 Feb 2008 00:54:41 -0000

Alain O'Dea — Tue, 26 Feb 2008 00:54:41 -0000

I think Joe was trying to get at a different kind of resetting of a variable. Think of Java.

String street = "1 Infinite Loop";
street = street.replace("1", "1A");

Erlang’s variables are a lot like Java finals:

final String street = "1 Infinite Loop";
final String correctedStreet = street.replace("1", "1A");

In Erlang:

Street = "1 Infinite Loop",
{ok, CorrectedStreet, _} = regexp:sub(Street, "1", "1A").

The ”=” operator in Erlang is not assignment although it may appear to be. It declares a constraint. It declares that the left hand and right hand sides are equal. By necessity everything on the right-hand side must be bound or set while the left-hand side may have unbound variables which will become bound to satisfy the constraint as declared.

2.6 One time assigments posted by Alexey Kuznetsov @ Mon, 25 Feb 2008 15:21:08 -0000

Alexey Kuznetsov — Mon, 25 Feb 2008 15:21:08 -0000

At end of 2.6 you can read bullet:

At this point you might be wondering how it’s possible to program with-
> out variables. How can you express something like X = X + 1 in Erlang?
> The answer is easy. Invent a new variable whose name hasn’t been used
> before (say X1), and write X1 = X + 1.

But my question is how it work for in for/next cycles. And IMHO right explanation is: recursion examples.

erl rr? posted by Darcy Laycock @ Wed, 06 Feb 2008 11:27:44 -0000

Darcy Laycock — Wed, 06 Feb 2008 11:27:44 -0000

Looks like your missing a closing } on the record declaration.

getting error on starting chat-client: lib_md5 missing? posted by Alain O'Dea @ Fri, 01 Feb 2008 01:56:31 -0000

Alain O'Dea — Fri, 01 Feb 2008 01:56:31 -0000

lib_md5.erl:

%% ---
%%  Excerpted from "Programming Erlang" 
%%  Copyrights apply to this code. It may not be used to create training material, 
%%  courses, books, articles, and the like. Contact us if you are in doubt.
%%  We make no guarantees that this code is fit for any purpose. 
%%  Visit <a href="http://www.pragmaticprogrammer.com/titles/jaerlang">http://www.pragmaticprogrammer.com/titles/jaerlang</a> for more book information.
%%---
-module(lib_md5).

%% modfied to use BIFs

-export([string/1, file/1, bin/1, binAsBin/1, digest2str/1]).

-define(BLOCKSIZE, 32768).
-define(IN(X,Min,Max), X >= Min, X =< Max).

%% md5:string(string())      -> BinDigest
%% md5:file(FileName)        -> {ok, BinDigest} | {error, E} 
%% md5:digest2str(BinDigest) -> StringDigest

%% md5:file works with chunks so should work correctly with extremely
%% large files

string(Str) -> digest2str(erlang:md5(Str)).

file(File) ->
    case file:open(File, [binary,raw,read]) of
    {ok, P} -> loop(P, erlang:md5_init());
    Error   -> Error
    end.

loop(P, C) ->
    case file:read(P, ?BLOCKSIZE) of
    {ok, Bin} ->
        loop(P, erlang:md5_update(C, Bin));
    eof ->
        file:close(P),
        {ok, erlang:md5_final(C)}
    end.

digest2str(Digest) -> bin2str(binary_to_list(Digest)).

bin2str([H|T]) ->
    {H1, H2} = byte2hex(H),
    [H1,H2|bin2str(T)];
bin2str([]) ->
    [].

byte2hex(X) -> 
    {nibble2hex(X bsr 4), nibble2hex(X band 15)}.

nibble2hex(X) when ?IN(X, 0, 9)   -> X + $0;
nibble2hex(X) when ?IN(X, 10, 15) -> X - 10 + $a.

%% compute the md5 checksum of a binary
bin(Bin) ->
    C1 = erlang:md5_init(),
    C2 = erlang:md5_update(C1, Bin),
    C3 = erlang:md5_final(C2),
    digest2str(C3).

binAsBin(Bin) ->
    C1 = erlang:md5_init(),
    C2 = erlang:md5_update(C1, Bin),
    erlang:md5_final(C2).

getting error on starting chat-client: lib_md5 missing? posted by wasiq hasan @ Mon, 28 Jan 2008 21:51:27 -0000

wasiq hasan — Mon, 28 Jan 2008 21:51:27 -0000

Hi, i am trying to execute chat clietn and geting the folowing error.
iam running it on linux.i did not find lib_md5.erl inth ecode i downloaded.

what i ned to make it run? here is te eror

make chat_client
mkdir -p /home/wasiq/.erlang_config/
cp conf /home/wasiq/.erlang_config/lib_chan.conf
make clean - clean up
erl -pa ../ -s chat_client test
Erlang (BEAM) emulator version 5.6 source async-threads:0 [kernel-poll:false]

Eshell V5.6 (abort with ^G)
1> chat_client disconnected unexpected:{‘EXIT’,<0>,normal}

=ERROR REPORT==== 28-Jan-2008::21:40:05 ===
Error in process <0> with exit value: {undef,[{lib_md5,string,[“pzbaplovtpmhazjuvcpdyqishAsDT67aQ”]},{lib_chan,authenticate,4},{lib_chan,connect,5},{chat_client,try_to_connect,4}]}

chat_client disconnected unexpected:{‘EXIT’,<0>, {undef, [{lib_md5,string,

{lib_chan,authenticate,4},
{lib_chan,connect,5},
{chat_client,try_to_connect,4}]}}

thanks
wasiq

Recent Posts in Programming Erlang | Pragmatic Forums